Discover New Possibilities!

Reading XML Data

This code demonstrates basic techniques to read an XML file. Ensure the highest support MSXML version is used when initializing the XML object.

  Dim oXML, oRoot, oNode, nameNode, codeNode

  ' Initialize the XML object using XMLDOM -- Not recommended!
  'Set oXML = Server.CreateObject( "Microsoft.XMLDOM" )

  ' Initialize the XML object using MSXML 3
  'Set oXML = Server.CreateObject( "Msxml2.DomDocument" )

  ' Initialize the XML object using MSXML 4
  Set oXML = Server.CreateObject( "Msxml2.DomDocument.4.0" )

  oXML.Async = False

  If( oXML.Load( Server.MapPath( "xml/payment_methods.xml" )) = True ) Then

    'Set Root object
    Set oRoot = oXML.DocumentElement

    ' Loop through each Payment Method
    For Each oNode in oRoot.ChildNodes
      Set nameNode = oNode.getElementsByTagName( "Name" ).item( 0 )
      Set codeNode = oNode.getElementsByTagName( "Code" ).item( 0 )

      Response.Write "CODE VALUE :: " & codeNode.text & "    NAME VALUE :: " _
                                  & nameNode.text & "<br />" & vbCRLF
    Next

    ' Free oRoot resources.
    Set oRoot = Nothing
  Else
    Response.Write "Error Code: " & oXML.ParseError & "<br />" & vbCRLF
    Response.Write "Error Description: " & oXML.ParseError.reason & "<br />" _
                                & vbCRLF
    Response.Write "Error File Position: " & oXML.ParseError.filepos & "<br />" _
                                & vbCRLF
    Response.Write "Error Line: " & oXML.ParseError.line & "<br />" & vbCRLF
    Response.Write "Error Line Position: " & oXML.ParseError.linepos & "<br />" _ 
                                & vbCRLF
    Response.Write "Error Source Text: " & oXML.ParseError.srcText & "<br />" _
                                & vbCRLF
  End If

  ' Free oXML resources.
  Set oXML  = Nothing